******************************************************************************
*                              Function QETAS
*                             ~~~~~~~~~~~~~~~~
*  Purpose:
*
*     Compute statistics Zeta(Q,n)
*
*  Usage:
*
*     QETAS ( Q, N )
*
*  Input arguments:
*
*     Q - significance level, %, REAL(8);
*         must be in the range 10^(-8)...40
*     N - number of data points, must be >= 3, INTEGER(4)
*
*  Returned value:
*
*     Zeta(Q,n), REAL(8)
*
*  Called routines:
*
*     QNORM
*
*  Method:
*
*        For M<=6 the table values are used (Note 4), for M>6 author's
*     approximation is used. Approximatioin error does not exceed:
*                   0.003 for N<=100,
*                   0.013 for N<=150,
*                   0.026 for N<=200,
*                   0.06  for N<=300,
*                   0.09  for N<=400,
*                   0.13  for N<=500.
*
*  Notes:
*
*        1. This statistocs is used to detect outliers when
*                      _                                  _
*                    X-X                          Sum(Xi-X)
*                   ----- > Zeta(Q,n),   S = sqrt --------- .
*                     S                              n-1
*
*        2. Allowed Q values are 20, 10, 5, 2, 1, 0.5, 0.2, 0.1, 0.05.
*        3. If given value of Q is not valid or N<3, -1 is returned.
*        4. Computaions are based on L.N. Bol'shev and N.V. Smirnov,
*     Tables of mathematical statistics (Tablitsy matematicheskoi statistiki),
*     3rd Edition, Moscow: Nauka, 1983, Table 4.8v multiplied by sqrt((n-1)/n).
*     For N>52, return value is computed using Eq. in p. 60 of this book. 
*
*
* (C) Z.Malkin, 1993-2026
*
* Distributed under the GNU General Public License.
*
* THE SOFTWARE IS PROVIDED "AS IS" AND THE AUTHOR DISCLAIMS ALL WARRANTIES WITH
* REGARD TO THIS SOFTWARE INCLUDING ALL IMPLIED WARRANTIES OF MERCHANTABILITY
* AND FITNESS. IN NO EVENT SHALL THE AUTHOR BE LIABLE FOR ANY SPECIAL, DIRECT,
* INDIRECT, OR CONSEQUENTIAL DAMAGES OR ANY DAMAGES WHATSOEVER RESULTING FROM
* LOSS OF USE, DATA OR PROFITS, WHETHER IN AN ACTION OF CONTRACT, NEGLIGENCE
* OR OTHER TORTIOUS ACTION, ARISING OUT OF OR IN CONNECTION WITH THE USE OR
* PERFORMANCE OF THIS SOFTWARE.
*
******************************************************************************

      FUNCTION QETAS ( Q, N )

      IMPLICIT NONE

      INTEGER(4), PARAMETER :: ITL = 4          ! last N in table
      INTEGER(4)  N, I, IQ, NM2

      REAL(8) QETAS, Q, P, QNORM

      REAL(8) QS(9)
     &  / 0.05D0, 0.1D0, 0.2D0, 0.5D0, 1D0, 2D0, 5D0, 10D0, 20D0 /

      REAL(8)  QT(9,ITL)
     &  / 1.155D0, 1.155D0, 1.155D0, 1.155D0, 1.155D0,
     &     1.155D0, 1.155D0, 1.153D0, 1.148D0,
     &    1.500D0, 1.500D0, 1.499D0, 1.498D0, 1.496D0,
     &     1.492D0, 1.481D0, 1.463D0, 1.425D0,
     &    1.785D0, 1.783D0, 1.780D0, 1.773D0, 1.764D0,
     &     1.749D0, 1.715D0, 1.672D0, 1.602D0,
     &    2.026D0, 2.019D0, 2.011D0, 1.993D0, 1.973D0,
     &     1.944D0, 1.887D0, 1.822D0, 1.729D0 /

      REAL(8)  QC(4,9)
     &  / 9.88133D-1, 4.31847D-5, -4.23242D0, 2.89774D0,
     &    9.87049D-1, 5.12540D-5, -3.85096D0, 2.51786D0,
     &    9.85744D-1, 5.91809D-5, -3.46890D0, 2.14099D0,
     &    9.83396D-1, 7.86601D-5, -2.95706D0, 1.63688D0,
     &    9.82771D-1, 8.45343D-5, -2.61076D0, 1.36652D0,
     &    9.81751D-1, 9.28241D-5, -2.25551D0, 1.09606D0,
     &    9.81622D-1, 9.41882D-5, -1.82875D0, 9.30596D-1,
     &    9.81392D-1, 9.79867D-5, -1.51368D0, 9.63600D-1,
     &    9.82902D-1, 8.54851D-5, -1.25140D0, 1.47314D0 /

* ----------------------------------------------------------------------------

      QETAS = -1D0

      DO I=1,9
         IF ( NINT(Q*100D0) .EQ. NINT(QS(I)*100D0) )  THEN
            IQ = I
            GOTO 1
         END IF
      END DO

      RETURN

   1  CONTINUE

      NM2 = N - 2
      IF ( NM2 .LT. 1 )  THEN
         RETURN
      ELSE IF ( NM2 .LE. ITL )  THEN
         QETAS = QT(IQ,NM2)
      ELSE
         P = 1D0 - 0.005D0*QS(IQ)/N
         QETAS = QNORM(P) *
     &      ( QC(1,IQ) + QC(2,IQ)*N + QC(3,IQ)/(N+QC(4,IQ)) )
      END IF

      END   ! QETAS
